: | : | :期货程序化 | :期货程序化研究 | :期货量化学习 | :期货量化 |
返回列表 发帖

【 ZigZag Fibonacci Plus】

龙听

Rank: 9Rank: 9Rank: 9

UID
2 
积分
2738934 
威望
1319463 布 
龙e币
1419471 刀 
注册时间
2009-12-3 
最后登录
2024-5-23 

Medal No.1
1# 跳转到 » 倒序看帖
打印
tT
发表于 2022-11-3 10:51 | 只看该作者

【 ZigZag Fibonacci Plus】

  1. inputs:  
  2.         RetraceType( 1 ) , { Choose: 1 Pnts, 2 Pct }
  3.         RetracePnts( 5 ) ,
  4.         RetracePct( 5 ) ,
  5.         ShowZigZagLines( True ) ,
  6.         ShowSwingPointLines( True ) ,
  7.         ZigZagLineColor( Magenta ) ,
  8.         ZigZagLineWidth( 1 ),
  9.         SwingHighColor( Black ) ,
  10.         SwingLowColor (Red ) ,
  11.         SwingLineStyle( Tool_Dotted ),
  12.         VertOffset( 0.25 ),
  13.         DecimalPlaces( 2 ),

  15.         {HamFon Fib inputs}
  16.         ShowOpenLine (False), ExtRight(True),
  17.         TextColor(LightGray),
  18.         HiLoColor (Magenta), OuterFibColor (DarkGreen),
  19.         MidColor(Magenta), InnerFibColor(Red), FibPlusColor(DarkGray), OpenColor (Darkbrown);
  20.         
  21. variables:
  22.         NewSwingPrice( 0 ) ,
  23.         LastSwingPrice(0 ) ,
  24.         SwingPrice( High ) , { used as a convenient 2-element array }
  25.         SwingDate( Date ) , { used as a convenient 2-element array }
  26.         SwingTime( Time ) , { used as a convenient 2-element array }
  27.         RetraceFctrUp( 1 + RetracePct * .01 ),
  28.         RetraceFctrDn( 1 - RetracePct * .01 ),
  29.         TLDir( 0 ), { TLDir = -1 implies prev TL dn, +1 implies prev TL up }
  30.         SaveSwing( false ) ,
  31.         AddTL( false ) ,
  32.         UpdateTL( false ) ,
  33.         TLRef( 0 ) ,
  34.     TLSwing( 0 ),
  35.         PeakTextRef( 0 ) ,
  36.     PeakStr("") ,

  38.         {HamFon variables inputs}
  39.         TLCreated (false), Redraw (false), Loop (0), Diff(0),
  40.         ArrayMax (11);

  42. vars: showDebug(FALSE);

  44. arrays: TrendLine[11] (0), DayValue[11] (0), FibText[11](0), FibLabel[11](" ");
  45.         

  47. //Create initial fib lines
  48. if CurrentBar = 1 then begin
  49.                 for loop=0 to ArrayMax begin {added Color for visual differentiation}
  50.                         if loop <= ArrayMax then begin
  51.                                 
  52.                                 TrendLine[loop] = TL_New (Date[1], Time[1], Low, Date, Time, Low);
  53.                                 If (loop = 4)  then
  54.                                         TL_SetColor (TrendLine[loop], MidColor)
  55.                                 else if (loop = 0) or (Loop = 1) then
  56.                                         TL_SetColor (TrendLine[loop], HiLoColor)
  57.                                 else if (loop = 3 ) or (loop = 5 ) then
  58.                                         TL_SetColor (TrendLine[loop], InnerFibColor)
  59.                                 else if (Loop = 2) or (loop = 6) then
  60.                                         TL_SetColor (Trendline[loop], OuterFibColor)
  61.                             {else if (Loop > 7) then
  62.                                         TL_setcolor(Trendline[loop], red)}

  64.                                 else TL_SetColor (TrendLine[loop], FibPlusColor);

  66.                                 TL_SetExtLeft (TrendLine[loop], false);
  67.                                 TL_SetExtRight (TrendLine[loop], True);
  68.                                 if loop = 4 then
  69.                                         TL_SetStyle(TrendLine[loop],Tool_dotted);
  70.                                 FibText[loop] = Text_New(Date, Time, Low, " " ) ;
  71.                                 Text_SetColor(FibText[loop], TextColor) ;
  72.                         end; // if loop
  73.                 end; // for loop

  75.         FibLabel[0] = "1" ; {Max Swing }
  76.         FibLabel[1] = "0" ; { Min Swing }

  78.         FibLabel[2] = ".236" ;
  79.         FibLabel[3] = ".382" ;
  80.         FibLabel[4] = ".5" ;
  81.         FibLabel[5] = ".618" ;
  82.         FibLabel[6] = ".764" ;
  83.         FibLabel[7] = ".886" ;
  84.         FibLabel[8] = "1.23" ;
  85.         FibLabel[9] = "1.5" ;
  86.         FibLabel[10] = "1.62" ;
  87.         FibLabel[11] = "2.00" ;

  89. end; //if currentbar


  92. { Candidate swings are just-confirmed, 3-bar (Str=1), SwingHi's and SwingLo's }

  94. NewSwingPrice = SwingHigh( 1, High, 1, 2 ) ;
  95. if NewSwingPrice  <> -1 then
  96.         begin
  97.         if ( RetraceType = 1 and TLDir <= 0 and NewSwingPrice >= SwingPrice + RetracePnts ) or
  98.            ( RetraceType = 2 and TLDir <= 0 and NewSwingPrice >= SwingPrice * RetraceFctrUp ) then
  99.                 { prepare to add new up TL }
  100.                 begin
  101.                 SaveSwing = true ;
  102.                 AddTL = true ;
  103.                 TLDir = 1 ;
  104.                 end
  105.         else if TLDir = 1 and NewSwingPrice >= SwingPrice then
  106.                 { prepare to update prev up TL }
  107.                 begin
  108.                 SaveSwing = true ;
  109.                 UpdateTL = true ;
  110.                 end ;
  111.         end
  112. else
  113. begin
  114.         NewSwingPrice = SwingLow( 1, Low, 1, 2 ) ;
  115.         if NewSwingPrice <> -1 then
  116.                 begin
  117.                 if ( RetraceType = 1 and TLDir >= 0 and NewSwingPrice <= SwingPrice - RetracePnts ) or
  118.                    ( RetraceType = 2 and TLDir >= 0 and NewSwingPrice <= SwingPrice * RetraceFctrDn ) then
  119.                         { prepare to add new dn TL }
  120.                         begin
  121.                         SaveSwing = true ;
  122.                         AddTL = true ;
  123.                         TLDir = -1 ;
  124.                         end
  125.                 else if TLDir = -1 and NewSwingPrice <= SwingPrice then
  126.                         { prepare to update prev dn TL }
  127.                         begin
  128.                         SaveSwing = true;
  129.                         UpdateTL = true ;
  130.                         end ;
  131.                 end ;
  132.         end ;

  134. if SaveSwing then
  135. { save new swing and reset SaveSwing }
  136. begin
  137.         SwingPrice = NewSwingPrice ;
  138.         SwingDate = Date[1] ;
  139.         SwingTime = Time[1] ;
  140. //        SaveSwing = false ;
  141. end ;

  143. if (showDebug) then
  144.         print(" AddTL === ", AddTL, "  UpdateTL == ", UpdateTL, "SaveSwing == ", SaveSwing, " TL Dir = ", TLDir);

  146. if AddTL then
  147. { add new TL and reset AddTL }
  148. begin
  149.         PeakTextRef = Text_New(Date, Time, Close, " ") ;
  150.         Text_SetColor(PeakTextRef, TextColor ) ;

  152.         if ShowZigZagLines then
  153.         begin
  154.                 TLRef = TL_New( SwingDate, SwingTime, SwingPrice, SwingDate[1], SwingTime[1],
  155.                  SwingPrice[1] ) ;
  156.                 Text_SetStyle(PeakTextRef, 2, 2 );
  157.                 TL_SetExtLeft( TLRef, false ) ;
  158.                 TL_SetExtRight( TLRef, false ) ;
  159.                 TL_SetSize( TLRef, ZigZagLineWidth ) ;
  160.                 TL_SetColor( TLRef, ZigZagLineColor ) ;
  161.                 LastSwingPrice = SwingPrice[1];
  162.         end ;

  164.         if ShowSwingPointLines then
  165.         begin
  166.                 TLSwing = TL_New( Date[1], Time[1], SwingPrice, Date, Time, SwingPrice ) ;
  167.                 if TLDir = -1 then
  168.                         TL_SetColor( TLSwing, SwingLowColor )
  169.                 else
  170.                         TL_SetColor( TLSwing, SwingHighColor ) ;                        
  171.                 TL_SetStyle( TLSwing, SwingLineStyle ) ;
  172.                 TL_SetExtLeft( TLSwing, False ) ;
  173.                 TL_SetExtRight( TLSwing, False ) ;
  174.         end ;

  176.         if TLDir = -1 then
  177.                 PeakStr = "" + NumToStr(SwingPrice,DecimalPlaces) + " / " + NumToStr(LastSwingPrice - SwingPrice, DecimalPlaces )
  178.         else
  179.                 PeakStr =  "" + NumToStr(SwingPrice,DecimalPlaces) + " / " + NumToStr(SwingPrice - LastSwingPrice, DecimalPlaces ) ;

  181.         Text_SetString(PeakTextRef, PeakStr );

  183.         if TLDir = -1 then
  184.                 Text_SetLocation(PeakTextRef, SwingDate, SwingTime, SwingPrice - VertOffset )
  185.         else
  186.                 Text_SetLocation(PeakTextRef, SwingDate, SwingTime, SwingPrice + VertOffset );

  188.         AddTL = false ;

  190. end
  191.         else if UpdateTL then
  192.         { update prev TL and reset UpdateTL }
  193.         begin
  194.         if ShowZigZagLines then
  195.                 TL_SetEnd( TLRef, SwingDate, SwingTime, SwingPrice ) ;

  197.         if ShowSwingPointLines then
  198.                 begin
  199.                 TL_SetEnd( TLSwing, SwingDate, SwingTime, SwingPrice ) ;
  200.                 TL_SetBegin( TLSwing, SwingDate, SwingTime, SwingPrice ) ;
  201.                 end ;
  202.         if TLDir = -1 then
  203.                 PeakStr = "" + NumToStr(SwingPrice,DecimalPlaces) + " / " + NumToStr(LastSwingPrice - SwingPrice, DecimalPlaces )
  204.         else PeakStr = "" + NumToStr(SwingPrice,DecimalPlaces) + " / " + NumToStr(SwingPrice - LastSwingPrice, DecimalPlaces ) ;
  205.         Text_SetString( PeakTextRef, PeakStr );
  206.         if TLDir = -1 then
  207.                 Text_SetLocation(PeakTextRef, SwingDate, SwingTime, SwingPrice - VertOffset)
  208.         else
  209.                 Text_SetLocation(PeakTextRef, SwingDate, SwingTime, SwingPrice + VertOffset);
  210.         UpdateTL = false ;
  211. end ;



  215.         {*************  HamFons'  FIB POINTS Code:
  216. goal is to call the  LAST SWING HI AND LAST SWING LO  from ABOVE CODE
  217. and draw Fib points between them *****************}

  219. if (showDebug) then
  220.         print("SaveSwing == ", SaveSwing, " TL Dir = ", TLDir);

  222. //Update Fib lines
  223. if SaveSwing then begin
  224.         if TLDir = -1 then
  225.         begin
  226.                 DayValue[0] = Swingprice;
  227.                 DayValue[1] = LastSwingprice;
  228.         end
  229.         else
  230.         begin
  231.                 DayValue[1] = Swingprice;
  232.                 DayValue[0] = LastSwingprice;
  233.         end ;

  235.                 Diff = DayValue[0] - DayValue[1];
  236. if (showDebug) then
  237.          print("Day0 = ", DayValue[0], " DayMax= ", DayValue[1], " Diff =", Diff, " TLDir = ", TLDir);

  239.                 DayValue[2] = DayValue[1] + Diff * .236;
  240.                 DayValue[3] = DayValue[1] + Diff * .382;
  241.                 DayValue[4] = DayValue[1] + Diff * .5;
  242.                 DayValue[5] = DayValue[1] + Diff * .618;
  243.                 DayValue[6] = DayValue[1] + Diff * .764;
  244.                 DayValue[7] = DayValue[1] + Diff * .886;
  245.                 DayValue[8] = DayValue[1] + Diff * 1.23;
  246.                 DayValue[9] = DayValue[1] + Diff * 1.5;
  247.                 DayValue[10] = DayValue[1] + Diff * 1.62;
  248.                 DayValue[11] = DayValue[1] + Diff * 2.00;

  250.         for loop=0 to ArrayMax begin
  251.                 { SetEnd before SetBegin }
  252.                 if TrendLine[loop] > 0 then begin
  253.                         TL_SetEnd (TrendLine[loop], Date, Time, DayValue[loop]);
  254.                         TL_SetBegin (TrendLine[loop], Date, Time, DayValue[loop]);
  255.                         end; // if TrendLine
  256.         end; // for loop

  258.         SaveSwing = False ;
  259. end ; // if SaveSwing

  261.         for loop=0 to ArrayMax begin

  263. if (showDebug) then               
  264.         print("Dayvalue[",Loop,"]= ", DayValue[Loop]);

  266.                 if FibText[loop] > 0 then begin
  267.                         Text_SetLocation(FibText[loop],Date,Time +1, Dayvalue[loop]);
  268.                         if TLDir = -1 then
  269.                                 Text_SetString(FibText[loop],NumToStr(DayValue[loop],DecimalPlaces) + " / " + FibLabel[loop] )
  270.                         else
  271.                                 Text_SetString(FibText[loop],NumToStr(DayValue[loop],DecimalPlaces) + " / " + FibLabel[loop] ) ;
  272.                         end ;
  273.         end;
复制代码

收藏 分享
论坛官方微信、群（期货热点、量化探讨、开户与绑定实盘）
 
期货论坛 - 版权/免责声明   1.本站发布源码(包括函数、指标、策略等)均属开放源码，用意在于让使用者学习程序化语法撰写，使用者可以任意修改语法內容并调整参数。仅限用于个人学习使用，请勿转载、滥用，严禁私自连接实盘账户交易。
  2.本站发布资讯(包括文章、视频、历史记录、教材、评论、资讯、交易方案等)均系转载自网络主流媒体，内容仅为作者当日个人观点，本网转载此文出于传递更多信息之目的，并不意味着赞同其观点或证实其描述。本网不对该类信息或数据做任何保证。不对您构成任何投资建议，不能依靠信息而取代自身独立判断，不对因使用本篇文章所诉信息或观点等导致的损失承担任何责任。
  3.本站发布资源(包括书籍、杂志、文档、软件等)均从互联网搜索而来，仅供个人免费交流学习，不可用作商业用途，本站不对显示的内容承担任何责任。请在下载后24小时内删除。如果喜欢，请购买正版，谢谢合作！
  4.龙听期货论坛原创文章属本网版权作品，转载须注明来源“龙听期货论坛”，违者本网将保留追究其相关法律责任的权力。本论坛除发布原创文章外，亦致力于优秀财经文章的交流分享，部分文章推送时若未能及时与原作者取得联系并涉及版权问题时，请及时联系删除。联系方式：http://www.qhlt.cn/thread-262-1-1.html
如何访问权限为100/255贴子：/thread-37840-1-1.html；注册后仍无法回复：/thread-23-1-1.html；微信/QQ群：/thread-262-1-1.html；网盘链接失效解决办法：/thread-93307-1-1.html

返回列表